Конвертация данных 2. Использование исходящих и входящих данных. Свойство "Получить из входящих данных"

Публикация № 1195038

Разработка - Обмен данными 1С

КонвертацияДанных Обмен ИсходящиеДанные ВходящиеДанные ПравилаОбмена

Разработка правил обмена с использованием исходящих и входящих данных. В качестве примера рассмотрена реальная задача конвертации номенклатуры через регистр сопоставления номенклатур. Статья предназначена в первую очередь для тех, кто только начинает осваивать Конвертацию данных.

1. Теория

В штатной справке по Конвертации данных об этих параметрах написано следующее:

ВходящиеДанные - Произвольный - произвольные вспомогательные данные, переданные правилу конвертации из других правил (например из правила выгрузки данных или правила конвертации свойств). Значение параметра, как правило, имеет тип Структура, где ключи значений соответствуют структуре свойств объекта приемника. Таким образом, при конвертации свойств (в правиле конвертации свойств), конвертируемые данные (или часть данных) могут быть получены из этого параметра.

ИсходящиеДанные - Произвольный - произвольные вспомогательные данные. Данные передаются по следующим правилам:

1) ПВД.ИсходящиеДанные -> ПКО.ВходящиеДанные

2) ПКО.ВходящиеДанные -> ПКС.ВходящиеДанные

3) ПКС.ИсходящиеДанные -> ПКО.ВходящиеДанные

Попробуем разобраться подробнее, как передаются данные параметры.

Шаг 1. ПВД (Правило выгрузки данных)

В правилах выгрузки данных создаем параметр ИсходящиеДанные и помещаем в него некоторое значение.

Шаг 2. ПКО (Правило конвертации объектов)

После выполнения ПВД, параметр передается в ПКО-приемник уже как ВходящиеДанные. К этому параметру можно обратиться в коде, например, поместив еще один элемент в структуру.

Если будет установлено хотя бы одно поле, получаемое из входящих данных, в ПКО добавится вкладка "Параметры, получаемые из входящих данных", где будет отображаться список соответствующих полей. Также отобразится кнопка "Структура запрашиваемых данных", которая позволит посмотреть, какую структуру входящих данных нужно передать в ПКО.

Шаг 3. ПКС (Правило конвертации свойств)

После выполнения кода в ПКО, параметр будет передан в ПКС как ВходящиеДанные. Здесь обращаем внимание на следующую особенность: из ПВД уходят ИсходящиеДанные, в ПКО приходят ВходящиеДанные. Из ПКО уходят ВходящиеДанные, в ПКС также приходят ВходящиеДанные.

Для того, чтобы свойству было присвоено значение из входящих данных, выставляем галку "Получить из входящих данных". Поле Источник очистится, т.к. оно уже потеряло свой смысл.

При совпадении наименовании ключа структуры входящих данных, поля будут заполнятся автоматически из входящих данных. Если наименование в структуре различаются, значение необходимо переназначить в ПКС вручную.

Шаг 4. Снова ПКО

Если поле имеет не примитивный тип данных, то система продолжит конвертацию объекта по правилу. Параметр ИсходящиеДанные, заданный в ПКС, будет передан в ПКО как ВходящиеДанные.

 

2. Практика

Задача: Необходимо настроить передачу документа (для примера будем использовать документ ПоступлениеТоваровУслуг) из базы Источника(1С:ERP Управление предприятием 2) в базу Приемник(Управление производственным предприятием 1.3) через регистр сведений "Сопоставление номенклатуры". У документа есть табличная часть Товары, в которой имеется поле "Номенклатура.

Номенклатура базы Источника должна заменяться на номенклатуру базы Приемника на основании найденного сопоставления, т.к. это эквивалентные номенклатуры, только хранящиеся в разных базах и имеющих разные наименования. В случае, если сопоставление не найдено - отказ в выгрузке всего документа.

Все передаваемые объекты, содержащие в себе поле Номенклатура, должны выгружаться через регистр сопоставлений.

Регистр хранится в базе Источнике.

Решение:

Для начала создадим ПКО для документа ПриобретениеТоваровУслуг, в качестве приемника необходимо указать документ ПоступлениеТоваровУслуг. На вопрос создать ли правила конвертации свойств автоматически, отвечаем утвердительно. Проверяем автоматически созданные ПКС на корректность. Далее создаем ПВД. Теперь можно приступать к доработке правил сопоставления.

Необходимо создать новую табличную часть Товары, в которой заменить номенклатуру Источника на номенклатуру Приемника. Если для выгружаемой Номенклатуры не будет найдено сопоставление, то отказ в выгрузке всего документа. Для этого в ПКО ПриобретениеТоваровУслуг в обработчике события Перед Выгрузкой добавим следующий код:

//Формируем Новую табличную часть, которую будем помещать во входящие данные
ТЧ = Источник.Товары.Выгрузить();

//Массив Номенклатур для загрузки в колонку ТЧ
МассивНоменклатур = Новый Массив;
//для того, чтобы не выполнять запрос в цикле, помещаем в запрос всю ТЧ Источника
Запрос = Новый Запрос;
Запрос.Текст =
"ВЫБРАТЬ
| СопоставлениеНоменклатурыУППERP.НоменклатураУПП КАК НоменклатураУПП,
| ПриобретениеТоваровУслугТовары.Номенклатура КАК Номенклатура
|ИЗ
| Документ.ПриобретениеТоваровУслуг.Товары КАК ПриобретениеТоваровУслугТовары
| ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.pll_СопоставлениеНоменклатурыУППERP КАК СопоставлениеНоменклатурыУППERP
| ПО ПриобретениеТоваровУслугТовары.Номенклатура = СопоставлениеНоменклатурыУППERP.НоменклатураERP
|ГДЕ
| ПриобретениеТоваровУслугТовары.Ссылка = &Источник"

Запрос.УстановитьПараметр("Источник", Источник);

РезультатЗапроса = Запрос.Выполнить();

ДетальныеЗаписи = РезультатЗапроса.Выбрать();

Пока ДетальныеЗаписи.Следующий() Цикл
	//проверяем, найдено ли соответствие
	Если ЗначениеЗаполнено(ДетальныеЗаписи.НоменклатураУПП) Тогда
		МассивНоменклатур.Добавить(ДетальныеЗаписи.НоменклатураУПП);
	Иначе
		//Отказ, если ничего не найдено
		Сообщить("Для документа " + Источник.Ссылка + " не найдено соответствие номенклатур ERP-УПП. Номенклатура "
		+ДетальныеЗаписи.Номенклатура.Наименование+". Выгрузка документа отменена!");
		Отказ = Истина;
		Прервать;
	КонецЕсли;
КонецЦикла;

Если НЕ Отказ Тогда
	//помещаем новую табличную часть во входящие данные
	ТЧ.Колонки.Удалить("Номенклатура");
	ТЧ.Колонки.Добавить("Номенклатура", Новый ОписаниеТипов("СправочникСсылка.НоменклатураУПП"));
	ТЧ.ЗагрузитьКолонку(МассивНоменклатур,"Номенклатура");
	ВходящиеДанные = Новый Структура;
	ВходящиеДанные.Вставить("Товары",ТЧ);
КонецЕсли;

Правила обмена почти готовы. Теперь необходимо установить галку для Свойства "Получить из входящих данных" для табличной части Товары.

Правила обмена готовы. Сохраняем созданные правила. Попытаемся выгрузить из базы Источника и загрузить в Приемник тестовый документ. После загрузки в Приемник видим, что номенклатура была передана корректно, но колонка ЕдиницаИзмерения не загрузилась.

Связана эта ситуация с тем, что свойство ЕдиницаИзмерения привязана к номенклатуре-владельцу. Следовательно, нужно передать из ПКС единиц измерения номенклатуру-владельца в ПКО ЕдиницыИзмерения.


Добавим в обработчик события Перед выгрузкой для ПКС ЕдиницаИзмерения следующий код:

ИсходящиеДанные = Новый Структура("Владелец");
ИсходящиеДанные.Владелец = ОбъектКоллекции.Номенклатура;

То, что указываем в ПКС как ИсходящиеДанные, в ПКО будет уже ВходящиеДанные.

В ПКО ЕдиницыИзмерения установим Галку "Получить из входящих данных" для Поля "Владелец".

Также не забудем дописать в ПКО ПриобретениеТоваровУслуг строку кода для выгрузки единиц измерений в ТЧ

 
 Исправленный код ПКО ПриобретениеТоваровУслуг для Единиц измерения

 

//Формируем Новую табличную часть, которую будем помещать во входящие данные 
ТЧ = Источник.Товары.Выгрузить();

//Массив Номенклатур для загрузки в колонку ТЧ
МассивНоменклатур = Новый Массив;
МассивЕдиницИзмерения = Новый Массив;
//для того, чтобы не выполнять запрос в цикле, помещаем	в запрос всю ТЧ Источника 
Запрос = Новый Запрос;
Запрос.Текст = 
"ВЫБРАТЬ
|	СопоставлениеНоменклатурыУППERP.НоменклатураУПП КАК НоменклатураУПП,
|	ПриобретениеТоваровУслугТовары.Номенклатура КАК Номенклатура
|ИЗ
|	Документ.ПриобретениеТоваровУслуг.Товары КАК ПриобретениеТоваровУслугТовары
|		ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.pll_СопоставлениеНоменклатурыУППERP КАК СопоставлениеНоменклатурыУППERP
|		ПО ПриобретениеТоваровУслугТовары.Номенклатура = СопоставлениеНоменклатурыУППERP.НоменклатураERP
|ГДЕ
|	ПриобретениеТоваровУслугТовары.Ссылка = &Источник";

Запрос.УстановитьПараметр("Источник", Источник);

РезультатЗапроса = Запрос.Выполнить();

ДетальныеЗаписи = РезультатЗапроса.Выбрать();

Пока ДетальныеЗаписи.Следующий() Цикл
	//проверяем, найдено ли соответствие  
	Если ЗначениеЗаполнено(ДетальныеЗаписи.НоменклатураУПП) Тогда
		МассивНоменклатур.Добавить(ДетальныеЗаписи.НоменклатураУПП);
		МассивЕдиницИзмерения.Добавить(ДетальныеЗаписи.Номенклатура.ЕдиницаИзмерения);
		
	Иначе
		//Отказ, если ничего не найдено
		Сообщить("Для документа " + Источник.Ссылка + " не найдено соответствие номенклатур ERP-УПП. Номенклатура "+ДетальныеЗаписи.Номенклатура.Наименование+
		". Выгрузка документа отменена!");
		Отказ = Истина;
		Прервать;
	КонецЕсли;
КонецЦикла;

Если НЕ Отказ Тогда
	//помещаем новую табличную часть во входящие данные
	ТЧ.Колонки.Удалить("Номенклатура");
	ТЧ.Колонки.Добавить("Номенклатура", Новый ОписаниеТипов("СправочникСсылка.НоменклатураУПП"));
	ТЧ.ЗагрузитьКолонку(МассивНоменклатур,"Номенклатура");
	ТЧ.Колонки.Добавить("ЕдиницаИзмерения", Новый ОписаниеТипов("СправочникСсылка.УпаковкиЕдиницыИзмерения"));
	ТЧ.ЗагрузитьКолонку(МассивЕдиницИзмерения,"ЕдиницаИзмерения");
	
	ВходящиеДанные = Новый Структура;
	ВходящиеДанные.Вставить("Товары",ТЧ);
КонецЕсли;

 

Как видим на рисунке ниже, табличная часть выгрузилась и загрузилась корректно.

Послесловие

Исходящие и Входящие данные -- неотъемлемый функционал КД2. Без него невозможно представить сложных обменов. К сожалению, на Инфостарте я не нашел статьи, в которой бы разбирались эти моменты, потому решил написать самостоятельно.

Для ситуации, если регистр сопоставления расположен в базе-приемнике, а не источнике, рекомендую прочесть эту статью.

Правила обмена разрабатывались в системе Конвертация данных, редакция 2.1 (2.1.8.2) для конфигураций 1С:ERP Управление предприятием 2 (2.4.10.62) и Управление производственным предприятием, редакция 1.3 (1.3.86.3). Справочник НоменклатураУПП и регистр сведений СопоставлениеНоменклатурыУППERP являются самостоятельно добавленными объектами и отсутствуют в типовой версии 1С:ERP Управление предприятием 2.

 

UPD.

За два с лишним месяца, прошедших с написания статьи, правила обмена были переосмыслены и переписаны с нуля несколько раз. Во многом благодаря комментариям ниже к посту.

Внесенные изменения и отпимизации:

1) Общая оптимизация (не нужно выгружать результат запроса в таблицу значений, обращаться через точку к переменным ссылочного типа и проч.);

2) В случаях, когда входящих и исходящих данных может быть несколько, либо вы дорабатываете уже существующие правила, неплохо бы делать такую вот проверку:

Если ТипЗнч(ВходящиеДанные) <> Тип("Структура") Тогда
	ВходящиеДанные = Новый Структура;
КонецЕсли;

Чтобы случайно не "обнулить" уже существующие данные в переменной.

3) Реализована подмена номенклатуры на сопоставленную на уровне запроса, а не его пост-обработкой в таблице значений;

4) "Сообщить()" везде заменено на "ОбщегоНазначения.СообщитьПользователю()";

5) Реализовано разделение табличной части Товары на две табличных части Товары и Услуги в зависимости от типа номенклатуры. (т.к. в УПП две табличных части, а не одна).

Отредактированный пример кода:

ТЗТовары = Новый ТаблицаЗначений();

Запрос = Новый Запрос;
Запрос.Текст = 
"ВЫБРАТЬ
|	pll_СопоставлениеНоменклатурыУППERP.НоменклатураУПП КАК Номенклатура,
|	ХарактеристикиНоменклатурыДополнительныеРеквизиты.Значение КАК Серия,
|	ПриобретениеТоваровУслугТовары.Номенклатура.Представление КАК ПредставлениеНоменклатуры,
|	ПриобретениеТоваровУслугТовары.Номенклатура.Типноменклатуры КАК ТипНоменклатуры,
|	ПриобретениеТоваровУслугТовары.Номенклатура.ЕдиницаИзмерения КАК ЕдиницаИзмерения,
|	ПриобретениеТоваровУслугТовары.*
|ИЗ
|	Документ.ПриобретениеТоваровУслуг.Товары КАК ПриобретениеТоваровУслугТовары
|		ЛЕВОЕ СОЕДИНЕНИЕ Справочник.ХарактеристикиНоменклатуры.ДополнительныеРеквизиты КАК ХарактеристикиНоменклатурыДополнительныеРеквизиты
|		ПО ПриобретениеТоваровУслугТовары.Характеристика = ХарактеристикиНоменклатурыДополнительныеРеквизиты.Ссылка
|		И ХарактеристикиНоменклатурыДополнительныеРеквизиты.Свойство = &СвойствоСерия
|		ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.pll_СопоставлениеНоменклатурыУППERP КАК pll_СопоставлениеНоменклатурыУППERP
|		ПО ПриобретениеТоваровУслугТовары.Номенклатура = pll_СопоставлениеНоменклатурыУППERP.НоменклатураERP
|ГДЕ
|	ПриобретениеТоваровУслугТовары.Ссылка = &Ссылка";

СвойствоСерия = ПланыВидовХарактеристик.ДополнительныеРеквизитыИСведения.НайтиПоНаименованию("Серия продукции");
Запрос.УстановитьПараметр("Ссылка", Источник);
Запрос.УстановитьПараметр("СвойствоСерия", СвойствоСерия);

РезультатЗапроса = Запрос.Выполнить();

Если РезультатЗапроса.Пустой() Тогда
	Отказ = Истина;	
КонецЕсли;

МассивУдаляемыхКолонок = Новый Массив;
МассивУдаляемыхКолонок.Добавить("ПредставлениеНоменклатуры");
МассивУдаляемыхКолонок.Добавить("ТипНоменклатуры");
МассивУдаляемыхКолонок.Добавить("Номенклатура1");
МассивУдаляемыхКолонок.Добавить("Серия1");

Для Каждого Колонка из РезультатЗапроса.Колонки Цикл	
	НайденныйЭлемент = МассивУдаляемыхКолонок.Найти(Колонка.Имя);
	
	Если НайденныйЭлемент = Неопределено Тогда
		ТЗТовары.Колонки.Добавить(Колонка.Имя);
	КонецЕсли;
	
КонецЦикла;

ТЗУслуги = ТЗТовары.СкопироватьКолонки();

Выборка = РезультатЗапроса.Выбрать();
ПредставлениеИсточника = Строка(Источник);
Пока Выборка.Следующий() Цикл
	Если Выборка.Номенклатура = NULL Тогда
		Отказ = Истина;
		ЗначениеСобытия = Новый Структура("ИмяСобытия, ПредставлениеУровня, Комментарий, ДатаСобытия");
		ЗначениеСобытия.ИмяСобытия = "Обмен данными. Ошибка сопоставления номенклатур";
		ЗначениеСобытия.ПредставлениеУровня = "Ошибка";
		ЗначениеСобытия.Комментарий = "Для объекта "+ПредставлениеИсточника +" и номенклатуры "+Выборка.ПредставлениеНоменклатуры+
		" не найдено сопоставление номенклатур. Объект не выгружен!";
		
		Параметры.СобытияДляЖурналаРегистрации.Добавить(ЗначениеСобытия);
		//Сообщаем пользователю
		ОбщегоНазначения.СообщитьПользователю(ЗначениеСобытия.Комментарий);
		
	ИначеЕсли Выборка.ТипНоменклатуры = Перечисления.ТипыНоменклатуры.Услуга Тогда
		ТЗ = ТЗУслуги;
	Иначе
		ТЗ = ТЗТовары;
	КонецЕсли;

	Если НЕ Отказ Тогда
		СтрокаТЗ = ТЗ.Добавить();
		ЗаполнитьЗначенияСвойств(СтрокаТЗ,Выборка);
	КонецЕсли;
КонецЦикла;

Если Не Отказ Тогда	
	Если ТипЗнч(ВходящиеДанные) <> Тип("Структура") Тогда
		ВходящиеДанные = Новый Структура;
	КонецЕсли;
	ВходящиеДанные.Вставить("Товары", ТЗТовары);
	ВходящиеДанные.Вставить("Услуги", ТЗУслуги);
КонецЕсли;

 

Специальные предложения

Комментарии
Избранное Подписка Сортировка: Древо развёрнутое
Свернуть все
1. Ibrogim 1152 19.02.20 10:28 Сейчас в теме
За теоретическую часть +

С практикой есть вопросы.
Например, уверены ли вы, что сортировка вашего массива будет всегда совпадать с сортировкой ТЗ (которую зачем то вы выгрузили из ТЧ, хотя можно было сконструировать при обходе запроса раз уж вы его всё равно обходите). Я вот не уверен, особенно если используется не MSSQL

"ДетальныеЗаписи.Номенклатура.ЕдиницаИзмерения" зачем двойное разыменование если можно получить в запросе единицу ?

Зачем вообще обходить результат в запросе если можно сразу отказаться в случае отсутствия сопоставления по какой либо позиции (например наложить условие в запросе и определить количество записей)

А зачем использовать не типовой pll_СопоставлениеНоменклатурыУППERP Когда можно пользоваться "СоответствияОбъектовИнформационныхБаз" ?
Drivingblind; +1 Ответить
2. Drivingblind 123 19.02.20 13:37 Сейчас в теме
(1)
С практикой есть вопросы.

Конечно есть. Это моя первая статья на Инфостарт, да и я сам не претендую на звание гуру 1С :)
Выложенный код не являются стопроцентно готовым решением, а, скорее, примером того, как работают Исходящие и Входящие данные. Но это вовсе не значит, что пример не должен работать.

(1)
Например, уверены ли вы, что сортировка вашего массива будет всегда совпадать с сортировкой ТЗ (которую зачем то вы выгрузили из ТЧ, хотя можно было сконструировать при обходе запроса раз уж вы его всё равно обходите). Я вот не уверен, особенно если используется не MSSQL

Да, вы правы, т.к. используется MSSQL, с такой проблемой не сталкивался. Сортировка по номеру строки не будет лишней. Спасибо за замечание. Поправлю.

"ДетальныеЗаписи.Номенклатура.ЕдиницаИзмерения" зачем двойное разыменование если можно получить в запросе единицу ?

Вы правы, нужно вынести этот момент в запрос. Исправлю.

Зачем вообще обходить результат в запросе если можно сразу отказаться в случае отсутствия сопоставления по какой либо позиции (например наложить условие в запросе и определить количество записей)

Вот тут не уверен, что это будет оптимальнее. Не знаю, что будет быстрее, два запроса (один на проверку, второй на формирование ТЧ), чем один запрос и перебор относительно небольшой (10-20 строк) табличной части. Мне кажется, это менять шило на мыло. Могу ошибаться, конечно. Плюс еще нужно выводить сообщение, какая конкретно номенклатура не сопоставлена.

А зачем использовать не типовой pll_СопоставлениеНоменклатурыУППERP Когда можно пользоваться "СоответствияОбъектовИнформационныхБаз" ?

Создан этот регистр потому, что Номенклатура в УПП не соответствует Номенклатуре в ERP напрямую, а соответствует Номенклатуре и Характеристике в ERP, но про это в тексте я не упомянул, т.к. на разработку правил обмена это никак не влияло.
3. Ibrogim 1152 19.02.20 15:07 Сейчас в теме
(2)
Не знаю, что будет быстрее, два запроса

Зачем два запроса? Можно в одном всё сделать.
Ну а то, что вы сообщаете несопоставленные номенклатуры... вы всё равно сообщаете только первую несопоставленную. Да и смысл что то сообщать?наверняка обмен автоматический и ваше "сообщить" сработает вникуда.

Да и вообще от "Сообщить" лучше отвыкать, чтоб не убирать его потом везде для получения 1С Совместимо )
22. SERGEJ64 04.05.20 11:03 Сейчас в теме
(2)
Создан этот регистр потому, что Номенклатура в УПП не соответствует Номенклатуре в ERP напрямую, а соответствует Номенклатуре и Характеристике в ERP, но про это в тексте я не упомянул, т.к. на разработку правил обмена это никак не влияло.

Добрый день! Подскажите, пжл, чем типовой регистр соответствия не подошел вам? Хочется понимать кейс. У нас аналогичная задача стоит, а согласно скриншотам вашего регистра соответствия в его структуре я не увидел характеристик. Ситуация заключалась в том, что несколько номенклатур УПП = одной номенклатуре ЕРП, но с создаваемыми в ЕРП характеристиками?
Drivingblind; +1 Ответить
23. Drivingblind 123 04.05.20 11:14 Сейчас в теме
(22)
Ситуация заключалась в том, что несколько номенклатур УПП = одной номенклатуре ЕРП, но с создаваемыми в ЕРП характеристиками?

Да, всё верно. Определенная продукция в УПП велась без учета характеристик (так исторически сложилось), а в ERP планируется вести её в разрезе характеристик. Поэтому отсутствует прямое соответствие 1:1.

Почему в итоговом коде запроса (в конце публикации) соединение идет без учета характеристик? Потому что этот вопрос пока временно был отложен, но изначальные планы были именно такие, как написано выше.
4. Eremkin 20.02.20 08:06 Сейчас в теме
Доброе утро. Автор безусловно молодец. За статью +
Вставлю свои 5 копеек про производительность. Попробуйте в ПВД вместо стандартной выборки поставить произвольный алгоритм, одним запросом собрать документы. Так же в обработке результата запроса можно сформировать ИсходящиеДаные (реквизиты + ТЧ) и использовать ВыгрузитьПоПравилу
Drivingblind; +1 Ответить
6. Drivingblind 123 24.02.20 09:13 Сейчас в теме
(4) Здравствуйте. Спасибо за оценку.

Попробуйте в ПВД вместо стандартной выборки поставить произвольный алгоритм, одним запросом собрать документы.

Да, конечно можно. Изначально при разработке правил обмена отказались от этой идеи, т.к. выгрузка идет по узлам планов обмена, а произвольный алгоритм не работал с планами обмена. Либо я не разобрался, как их подружить.
Но для примера можно и в ПВД сразу всё сделать.
8. Eremkin 24.02.20 11:59 Сейчас в теме
(6) В обработчике самой конвертации "Перед выгрузкой данных" вставить в параметры для примера

ОрганизацииВыгрузки = УзелДляОбмена.Организации.Выгрузить().ВыгрузитьКолонку("Организация");
Параметры.Вставить("ОрганизацияВыгрузки", ОрганизацииВыгрузки[0]) в

И уже в ПВД можно использовать данный параметр для выборки в запросе. Таким образом можно отсечь лишние данные.
9. Drivingblind 123 25.02.20 08:38 Сейчас в теме
(8) Вы предлагаете помещать узел обмена в параметр, а потом делать выборку запросом в ПВД наподобие следующей? Верно я понимаю?
Запрос.Текст =
"ВЫБРАТЬ ПриобретениеТоваровУслугТовары.*
|ИЗ
|	Документ.ПриобретениеТоваровУслуг.Товары КАК ПриобретениеТоваровУслугТовары
|		ВНУТРЕННЕЕ СОЕДИНЕНИЕ Документ.ПриобретениеТоваровУслуг.Изменения КАК ПриобретениеТоваровУслугИзменения 
|		ПО ПриобретениеТоваровУслугИзменения.Ссылка = ПриобретениеТоваровУслугТовары.Ссылка
|ГДЕ
|	ПриобретениеТоваровУслугИзменения = &Узел";

Запрос.УстановитьПараметр("Узел", Параметры.УзелОбмена);
Показать
10. Eremkin 25.02.20 10:04 Сейчас в теме
(9)Добрый день. Мне не совсем понятно все таки для чего вам узел обмена? Какая проблема решается?
12. Drivingblind 123 26.02.20 05:26 Сейчас в теме
(10) Здравствуйте. Узел обмена нужен для выборки объектов, зарегистрированных в узле. Обмен происходит не всеми объектами, а только зарегистрированными в узле.
13. Eremkin 26.02.20 07:42 Сейчас в теме
(12) ага, становится более понятнее. При конвертации и так берутся только те объекты, которые зарегистрированы в узле. Или у вас какой-нибудь самописный план обмена, где для документов по крайней мере стоит признак авторегистрация? И не требуются выгружать документы с каким-либо призраком? Давайте копнем ещё. Какая проблема возникает после конвертации в базе приемнике?
14. Drivingblind 123 26.02.20 08:17 Сейчас в теме
(13) Не совсем понимаю, о чем вы. Да, есть планы обменов, в которых регистрируются объекты к обмену. Каждый раз переносить все документы не нужно. Переносятся только зарегистрированные в узле.
Если мы установим узел обмена в обработке Универсальный обмен xml и попытаемся сделать произвольный алгоритм ПВД -- получим ошибку, о чем я уже писал выше.

(13)
Давайте копнем ещё. Какая проблема возникает после конвертации в базе приемнике?

Тоже не совсем понимаю. Пока никакая.
15. Eremkin 26.02.20 13:17 Сейчас в теме
(14)Так-с, еще интереснее стало. Вы открываете внешнюю обработку Универсальный обмен xml, устанавливаете узел обмена для отбора и пытаетесь выгрузить в файл? Верно? Или мы с вами о разных вещах говорим?
16. Drivingblind 123 26.02.20 13:40 Сейчас в теме
(15) Да, именно это.
Прикрепленные файлы:
17. Eremkin 27.02.20 10:53 Сейчас в теме
(16) Я сегодня вечером дома постараюсь посмотреть. Где-то аналогичный кейс у меня был по решению такой задачи
18. Eremkin 27.02.20 22:31 Сейчас в теме
(17)Попробовал простенький пример. Вроде все норм получилось
Прикрепленные файлы:
Drivingblind; +1 Ответить
19. Drivingblind 123 28.02.20 05:36 Сейчас в теме
(18) в комментарии (9) я именно про это и написал :D
в любом случае, спасибо за идею. Статью дополню, как будет время свободное.
20. Eremkin 28.02.20 07:11 Сейчас в теме
(19)да, но я хотел проверить все-таки ))
21. Drivingblind 123 29.04.20 19:31 Сейчас в теме
(4)
(1)
Обновил статью, исправил всякие ошибки и обращения через точку. Спасибо за критику
5. Megaiff 21.02.20 00:09 Сейчас в теме
в первую очередь + за картинку точно себя увидел. Особенно когда не так часто пользуешься. А то помню смотрел Гилева все делал но без практики и задач вылетает из головы все а тут так много тонкостей ))
Drivingblind; +1 Ответить
7. Drivingblind 123 24.02.20 09:15 Сейчас в теме
(5) мне очень помогли видеоуроки Ильи Леонтьева по КД2 на YouTube. Для начинающих, мне кажется, самое то
Megaiff; acanta; +2 Ответить
11. Megaiff 25.02.20 22:59 Сейчас в теме
(7)
Ильи Леонтьева

Спасибо за инфу. Нашел может кому то пригодится
Не реклама https://www.youtube.com/channel/UCtSVt800z-nHQK0fAFENX-A/videos.
24. Yashazz 3276 04.05.20 12:42 Сейчас в теме
Да. Для совсем начинающих - полезная статья.
25. e-9 20 30.06.20 15:50 Сейчас в теме
Своим гражданским долгом считаю везде, где только идет речь про Вх/ИсходящиеДанные, предупредить о "обмане" КД2 - см. скрин. А именно: в обработчике ПВД "Перед выгрузкой" нужно объявлять ВХодящиеДанные, а не ИсходящиеДанные - если потом мы хотим в каких-то ПКС получать значения из входящих данных.
(Убил кучу времени, пока понял, что тут ошибка в мануале)
Прикрепленные файлы:
26. Drivingblind 123 02.07.20 17:59 Сейчас в теме
(25) Там следующая логика:
1) ПВД.ИсходящиеДанные -> ПКО.ВходящиеДанные
2) ПКО.ВходящиеДанные -> ПКС.ВходящиеДанные
3) ПКС.ИсходящиеДанные -> ПКО.ВходящиеДанные
27. e-9 20 03.07.20 12:25 Сейчас в теме
(26) я умею читать) даже мануалы. Откуда Вы и скопировали "логику". А в мануале нет деления на конкретные обработчики.
Перечитайте пожалуйста мое сообщение: в обработчике ПВД "Перед выгрузкой" - не так, как написано в информации по обработчикам. Можете проверить - объявите именно в этом обработчике Исходящие данные, и попробуйте в ПКО, заполнить в каком-то ПКС значение из входящих данных.
28. Drivingblind 123 04.07.20 07:34 Сейчас в теме
(27) да я и не скрываю, что взял оттуда :)
Проверю у себя, если ошибка воспроизведется, дополню статью.
Оставьте свое сообщение

См. также

Загрузка табелей рабочего времени из файлов Excel Промо

Зарплата Обработка документов Учет рабочего времени Загрузка и выгрузка в Excel v8 v8::СПР ЗУП3.x Россия БУ Абонемент ($m)

Обработка по загрузке в типовой документ «Табель» конфигурации ЗУП 3.1 данных из файлов MS Excel, согласно шаблону.

18.10.2019    7779    5    HostHost    0    

Разбираемся с web-kit в 1С, на примере интеграции TinyMCE в управляемую форму в УТ 11.4. Допиливаем обмен с сайтом в УТ 11.4

Обмен данными 1С Интеграция Адаптация типовых решений v8 v8::УФ УТ11 Абонемент ($m)

Многие уже знают, что в релизе платформы 8.3.14.1565, браузер Internet Explorer был заменен на Web-Kit, это на самом деле большой шаг вперед, но я уверен, многим, как и мне, пока не совсем понятно, что к чему. Возник опыт использования web-kit в 1С, вызова JS из 1С и вызова 1С из JS. Давайте вместе попробуем понять, чем одно отличается от другого, и заодно сделаем, что-нибудь полезное. Да и наверняка многим придется переписывать свои подобные поделки после обновления на новую платформу, так что надеюсь мой опыт окажется полезным.

2 стартмани

08.12.2019    7447    12    Бэнни    25    

Обмен без правил. От простого к сложному

Перенос данных из 1C8 в 1C8 v8 1cv8.cf Абонемент ($m)

Пишем обмен с нуля, разбираемя с разными способами сериализации, учимся редактировать XML документы, создаем XDTO и Web service, осваиваем Script variant - English.

1 стартмани

16.01.2019    21319    14    nbeliaev    26    

Универсальная выгрузка/загрузка данных для отличающихся конфигураций (JSON, Такси+ОФ) Промо

Перенос данных из 1C8 в 1C8 Универсальные обработки Распределенная БД (УРИБ, УРБД) v8 1cv8.cf Абонемент ($m)

Простой перенос через JSON данных между двумя базами 1С (документов, справочников, ПВХ, ПВР, счетов). Аналогична произвольной выгрузке в типовой "Выгрузка/загрузка XML", но может использоваться для отличающихся конфигураций. Подходит для любых пар баз с любым интерфейсом (управляемый + обычный). Без настроек. Не требует идентичности конфигураций и платформ. При переносе типы данных сопоставляются по наименованиям метаданных, объекты и ссылки по UID.

1 стартмани

22.10.2014    202582    3085    ekaruk    179    

Выполнение запроса в другой базе 1С без com-соединения. HTTP-сервис

Перенос данных из 1C8 в 1C8 v8 1cv8.cf Абонемент ($m)

Выполнение любого запроса с параметрами из одной базы 1С в другую. Используя HTTP-сервис. Посредством POST-запроса и JSON.

1 стартмани

30.11.2018    18248    22    John_d    21    

Пример получения данных из другой базы 1С через Web-сервис

Перенос данных из 1C8 в 1C8 v8 Россия Абонемент ($m)

В данной статье описан пример получения данных справочника из другой базы 1С через Web-сервис.

1 стартмани

11.11.2018    25664    24    flyDrag    29    

Прыг-Скок...или из MS EXCEL в 1С (8.2) (открытый код) Промо

Обработка документов Обработка справочников Загрузка и выгрузка в Excel v8 1cv8.cf Абонемент ($m)

Универсальная загрузка данных из Microsoft Office Excel. Автоматическая загрузка из любых по форме документов с очень удобным редактором. Почти готовый шаблон для любой конфигурации. Не требует регистрации-бесплатно.

1 стартмани

16.09.2015    60090    351    Tatitutu    48    

Опыт проведения сложных переносов данных на 1С

Перенос данных из 1C8 в 1C8 Интеграция v8 КД Абонемент ($m)

В статье я расскажу про опыт сложных переносов на платформе 1С:Предприятие. Она будет адресована в первую очередь разработчикам 1С, которые уже имеют опыт использования методики «Конвертация данных» (как второй, так и третьей редакции) – я думаю, это большинство из нас. • Я расскажу про различные методики организации переносов данных. • Мы рассмотрим рекомендуемые способы оптимизации правил конвертации, которые позволят вам быстрее выполнять свои переносы. • Также мы разберем, какие могут возникнуть сложности в ходе переноса данных. • Я покажу сравнительный анализ по ряду параметров инструментов «Конвертация данных» второй редакции и третьей, которая вышла уже более года назад.

1 стартмани

30.07.2018    34990    8    primat    14    

Вы больше не будете разбирать Excel как раньше

Загрузка и выгрузка в Excel v8 1cv8.cf Абонемент ($m)

Кому не приходилось разбирать файлы в формате Excel? Все матерятся, плюются, требуют обещаний что "это в последний раз", но таки пишут загрузку из Excel. Потом форматы меняются, строки съезжают, колонки переставляют... Вам это не надоело?

1 стартмани

07.05.2018    27192    61    m-rv    34    

Правила конвертации документов ЗУП 2.5 - ЗУП 3.1

Обмен через XML Зарплата Перенос данных из 1C8 в 1C8 Зарплата v8 v8::СПР ЗУП2.5 ЗУП3.x Россия БУ Абонемент ($m)

Правила конвертации документов ЗУП 2.5 - ЗУП 3.1. Позволяют вести параллельную работу в базах ЗУП редакций 2,5 и 3.1.

10 стартмани

06.03.2018    36895    152    kostya_whiskas    24    

Перенос объектов 1С Промо

Перенос данных из 1C8 в 1C8 v8 v8::УФ 1cv8.cf Абонемент ($m)

Простой и наглядный перенос объектов между любыми базами 1С 8 с предварительным анализом на возможные различия в данных (через файл, через интернет, через буфер обмена). Интерактивная настройка правил обмена на стороне источника и получателя. В обработке есть удобный обзор по подсистемам, поиск и обработка данных по заданному фильтру. Сравнение объектов, поиск ссылок. Конструктор кода по созданию объектов, написание скриптов и отладка мини-функций в УФ. Отключение/включение регламентных заданий. Регистрация/снятие с регистрации объектов в планах обмена. И многое другое. Инструменты администратора в одной обработке.

1 стартмани

16.03.2015    86860    1377    moolex    193    

Организация обмена с базой филиала (розничного магазина) в торговой сети через XML (универсальный обмен)

Обмен через XML Перенос данных из 1C8 в 1C8 Розничная торговля Розничная торговля v8 КД УТ11 Розничная и сетевая торговля (FMCG) Абонемент ($m)

В статье по шагам рассматривается создание обмена между центральной базой и базами филиалов на базе конфигурации УТ 11. Для решения поставленной задачи было решено не использовать РИБ, т.к. требуется односторонний обмен ограниченным набором данных, к тому же по определенным условиям. Обмен реализован на основе типовой синхронизации на основе универсального обмена в формате EnterpriseData. Данная публикация может быть полезна внедренцам, которые работают с торговыми сетями, в том числе по модели франчайзинга.

1 стартмани

26.02.2018    35575    13    Kutuzov    18    

Создание в 1С 7.7 XML в формате EnterpriseData (универсальный формат обмена), версия 1.5. Инструкции и примеры переноса данных из устаревшей конфигурации 1С 7.7 в любую современную 1С 8.3, поддерживающую EnterpriseData, через Конвертацию данных 3

Перенос данных из 1С7.7 в 1C8.X Обмен через XML v7.7 v8 1cv7.md Россия Абонемент ($m)

Воспользоваться современным средством переноса данных "Конвертация данных 3.0.5.3" можно только выгрузив из системы - источника данных XML в формате обмена данными EnterpriseData. В этой публикации можно скачать приемы выгрузки из 1С 7.7 универсального формата обмена для Конвертации данных 3. Выполняем перенос данных из «1С:Предприятие 7.7» в «1С:Предприятие 8.3». Используем Конвертацию данных КД 3.0 из 1c 7.7 --> 1С 8.3. На первой стадии еще не опубликовано иного способа подложить файл для Конвертации данных 3 кроме как сформировать его вручную, постараемся решить данную проблему.

1 стартмани

26.02.2018    36329    51    ksnik    3    

Проверка данных после неполного ("нового") переноса из ЗУП 2.5 в ЗУП 3.1

Зарплата Бухгалтерский учет Перенос данных из 1C8 в 1C8 Зарплата v8 v8::СПР ЗУП3.x Россия БУ Абонемент ($m)

Описаны данные, которые необходимо проверить после неполного ("нового") переноса из ЗУП 2.5 в ЗУП 3.1. Описано, на что необходимо обратить внимание, где найти перенесенные данные, что НЕ переносится, где найти настройки.

1 стартмани

17.01.2018    28654    144    btydj    3    

Соответствия объектов обмена Промо

Распределенная БД (УРИБ, УРБД) Перенос данных из 1C8 в 1C8 v8 КА1 Россия Абонемент ($m)

Обработка позволяет проверять, исправлять ошибки, добавлять и удалять соответствия объектов в обменах данными между конфигурациями на основе «Комплексной автоматизации 1.1» или похожими конфигурациям. Подходит для обменов с использованием регистра сведений «СоответствиеОбъектовДляОбмена».

2 стартмани

26.08.2016    20043    11    xxxelaaa    0    

Расчет начисления зарплаты со сложной формулой, по данным из внешнего источника. ЗУП 3.1

Обработка документов Загрузка и выгрузка в Excel Зарплата Зарплата v8 v8::СПР ЗКГУ3.0 ЗУП3.x БУ Абонемент ($m)

Расчет начисления зарплаты со сложной формулой, по данным из внешнего источника по данным экономического отдела. ЗУП 3.1.

3 стартмани

20.12.2017    44751    31    mvv1975    7    

Приемы эффективной загрузки данных из Excel в 1С

Загрузка и выгрузка в Excel v8 1cv8.cf Абонемент ($m)

Показаны приемы эффективной работы с Excel для загрузки данных в 1С.

1 стартмани

13.12.2017    45781    89    alexey.kutya    82    

Синхронизация данных по правилам КД2.0

Перенос данных из 1C8 в 1C8 v8 1cv8.cf Абонемент ($m)

Новый инструмент для сравнения и загрузки данных, сочетающий в себе: гибкость запросов (используются для сопоставления объектов); наглядный вывод отличий; удобный отбор загружаемых данных; возможность пообъектной синхронизации двух баз по правилам КД2 с помощью вызова обработки "Универсальный обмен XML" в базе-источнике через COM-соединение.

1 стартмани

27.08.2017    22567    111    vikad    35    

Выгрузка и загрузка данных из файла Excel с поиском по любым полям (есть поиск по ссылке, всего три итерации поиска. Управляемые формы или "Такси") Промо

Загрузка и выгрузка в Excel Обработка документов v8 v8::УФ 1cv8.cf Абонемент ($m)

Обработка позволяет загружать данные с поиском по ссылке как для загружаемого объекта, так и его свойств. Загружает справочники, документы, планы видов характеристик. Будет полезна как замена использования конвертации данных для задач переноса, а также как классическая загрузка из табличного документа (Excel). Поиск объекта при загрузке выполняется до трех раз с разными полями поиска (поля поиска настраиваются). Также реализована выгрузка в Excel по ссылкам. У обработки удобный интерфейс, в котором разберется даже начинающий пользователь. Загрузка накладных из файлов xls реализована с интеллектуальным поиском колонок с данными. В интеллектуальном поиске поддерживаются все основные типовые печатные формы.

5 стартмани

16.10.2015    57311    502    primat    33    

Загрузка дополнительных реквизитов и сведений справочника Номенклатура из Excel и таблиц УТ 11, ERP 2

Обработка справочников Загрузка и выгрузка в Excel Учет ТМЦ Учет ТМЦ v8 v8::ОУ ERP2 УТ11 Россия УУ Абонемент ($m)

Внешняя обработка "Загрузка дополнительных реквизитов и сведений справочника Номенклатура"

1 стартмани

07.08.2017    37142    238    Windyhead    32    

Правила обмена ЗУП 3.1 - БП 2.0 и ЗУП 3.1 - УПП 1.3 (отражение, ведомости и справочники)

Перенос данных из 1C8 в 1C8 Обмен через XML Зарплата Управление персоналом (HRM) Зарплата Управление персоналом (HRM) v8 v8::БУ v8::СПР БП2.0 БП3.0 ЗУП3.x Россия БУ Абонемент ($m)

Правила обмена для выгрузки документов "Отражение зарплаты в бухучете", "Ведомость в банк", "Ведомость в кассу", справочников "Сотрудники" и "Физические лица"

1 стартмани

01.08.2017    75609    1543    forseil    209    

Перенос справочников и документов из УТ 10.3 в БП 3.0

Перенос данных из 1C8 в 1C8 v8 УТ10 БП3.0 Россия БУ НУ УУ Абонемент ($m)

Синхронизация справочников и документов из Управление торговлей 10.3 в Бухгалтерию предприятия 3.0. Обработка не затрагивает штатный механизм. Подключение и перенос документов происходит посредством OLE. Без ввода начальных остатков.

10 стартмани

25.07.2017    20954    14    2casp    5    

Выгрузка данных из УТ 10.3 в БП 3.0 (своими руками) Промо

Перенос данных из 1C8 в 1C8 v8 УТ10 БП3.0 Россия Абонемент ($m)

Старая добрая, позабытая многими выгрузка из УТ 10.3 в БП 1.6. Ее еще можно оживить, и она послужит на благо всем желающим, всем уставшим от автоматических обменов.

3 стартмани

30.10.2014    38184    178    TESL    40    

 Интеграция 1С и C#. Обращение к 1С через COM. Создание номенклатуры и выполнение запроса к 1С из C# на примере интеграции с Союз-PLM (система информационной поддержки жизненного цикла изделий). Обработка «Загрузка заказа на сборку». (ERP)

Загрузка и выгрузка в Excel Внешние источники данных Интеграция v8 ERP2 Абонемент ($m)

Союз-PLM представляет собой полнофункциональный программный комплекс для решения  широкого спектра задач управления инженерной технической информацией наукоемких изделий и сложных инженерных объектов в области машиностроения, приборостроения, архитектуры, строительства. На практике, это управление конструкторской документацией, интегрированное с САПР, бизнес-процессы, файловый архив. Все это работает в SQL и шевелится с помощью скриптов на C#. Скрипты свободно  отлаживаются в MS Visual Studio. Подробнее смотрите на их сайте: http://www.programsoyuz.ru/products/system-soyuz-plm.html  Редактирование, конструирование и использование бизнес-процессов на порядок лучше систем на базе 1С из тех, что я изучил.

1 стартмани

25.07.2016    41645    4    milkers    2    

Выгрузка/загрузка данных в формате JSON v 1.0.6

Распределенная БД (УРИБ, УРБД) Перенос данных из 1C8 в 1C8 v8 1cv8.cf Абонемент ($m)

Обработка предназначена для обмена данными между схожими конфигурациями в формате JSON. Этот формат обладает рядом существенных преимуществ по сравнению с xml и прочими популярными форматами. В отличие от существующих аналогов, обработка не использует никаких дополнительных библиотек. (де)Сериализация всех объектов происходит средствами встроенного языка и методов ЗаписатьJSON() и ПрочитатьJSON(). Работает на платформе версии не ниже 8.3.6.

3 стартмани

27.01.2016    42410    326    kser87    41    

Прайс-лист с картинками в EXCEL из 1С: УТ10, УПП, КА (с формой заказа)

Ценообразование, прайсы Загрузка и выгрузка в Excel Оптовая торговля Оптовая торговля v8 КА1 УТ10 УПП1 Абонемент ($m)

Обработка для формирования прайса в EXCEL с формой заказа. Выгрузка картинок, характеристик, нескольких цен, остатков. Расчет заказа прямо в прайсе.

9 стартмани

26.11.2015    34992    59    spy-83    19    

Интерфейс сопоставления объектов для обмена (для типового регистра СоответствиеОбъектовДляОбмена) Промо

Инструментарий разработчика Универсальные обработки Перенос данных из 1C8 в 1C8 v8 КА1 БП2.0 ЗУП2.5 УТ10 УПП1 Абонемент ($m)

Вы внедряете обмен данными между двумя типовыми или основанными на типовых БД и вам необходим инструмент, чтобы сопоставить между собой справочники этих конфигураций? Вы хотите навести порядок в обмене данными, потому что вам надоело вылавливать дублирующиеся объекты? Вам очень хочется перепоручить сопоставление объектов обменивающихся баз пользователям, но нет подходящего и понятного пользователям интерфейса? Тогда вам нужна именно эта обработка!

4 стартмани

11.11.2015    37414    133    catsam    8    

[COM] Перенос данных через COMConnector

Перенос данных из 1C8 в 1C8 v8 1cv8.cf Россия Абонемент ($m)

Обработка обмена между двумя информационными базами схожей (не обязательно совпадающей) структуры. Изначально была заточена под бухгалтерию предприятия, сейчас используется для для обменов через COM любых конфигураций с режимом запуска "Управляемое приложение". Ближайший аналог - выгрузка-загрузка XML, но здесь нет промежуточных файлов выгрузки/загрузки, и обмен не прекращается в случае, когда состав реквизитов источника и приёмника различен!!! 22.05.2020 Версия 5.2.3.4 Исправлена ошибка в таблице соответствия планов счетов, любезно подсказанная Fox_65. Все реквизиты таблицы соответствия теперь с типом строка, чтобы избежать в дальнейшем повторения этой ошибки, если обработку вдруг будет сохранена в конфигурации, не имеющей Плана счетов Хозрасчтный. Соответственно изменены заполнеие таблицы соответствия счетов и поиск счетов между базами. Из нового - добавлен возможность переноса Счетов на оплату покупателю из КА 1.1 в Заказ клиента КА 2.4 (случилась такая хотелка у клиента) (тестировалось на платформе 8.3.17.1386, БП 3.0.77.89 )

2 стартмани

23.11.2015    47134    642    Alex_E    208    

Загрузка УПД в Бухгалтерию 3.0

Обработка документов Загрузка и выгрузка в Excel Оптовая торговля Оптовая торговля v8 v8::БУ БП3.0 Россия БУ Абонемент ($m)

Загрузка УПД из Excel в Бухгалтерию предприятия 3.0, с добавлением номенклатуры, ГТД, стран происхождения.

3 стартмани

20.10.2015    20614    16    teyana    12    

Полезные приемы при работе с Excel из 1С (Версия 3.1)

Практика программирования Разработка внешних компонент Загрузка и выгрузка в Excel v8 1cv8.cf Абонемент ($m)

Программисту 1С часто приходится работать с таблицами Excel из 1С. Я постарался собрать небольшой FAQ и набор функций для работы с файлами Excel. Надеюсь, кому-то будет полезна данная статья.

1 стартмани

22.09.2015    180707    430    Zerocl    65    

Универсальное средство чтения файлов Excel Промо

Универсальные обработки Загрузка и выгрузка в Excel v8 1cv8.cf Абонемент ($m)

Унифицируем чтение файлов Excel, читаем "неудобные" файлы, переносим содержимое таблиц Excel через буфер обмена.

5 стартмани

27.03.2013    28816    35    Infector    4    

Управление изменениями в планах обмена (Управляемое приложение) v 1.0

Распределенная БД (УРИБ, УРБД) Внешние источники данных Перенос данных из 1C8 в 1C8 v8 1cv8.cf Абонемент ($m)

Простая в использовании и наглядная обработка для регистрации изменений или отмены регистрации в планах обмена используя гибкие возможности отбора СКД.

2 стартмани

15.08.2015    28834    45    kser87    3    

Обмен прайс-листами и анализ ценовой политики конкурентов, партнёров и поставщиков в программе 1С:Предприятие

Ценообразование, прайсы Обработка документов Загрузка и выгрузка в Excel Ценообразование, анализ цен Ценообразование, анализ цен v8 УТ10 УПП1 УУ Абонемент ($m)

Универсальная программа для загрузки Прайс-листов в базу 1С:Предприятия 8. Основные достоинства: простота использования и широкие функциональные возможности поиска товаров для записи цен. Область применения: обмен прайс-листами и анализ ценовой политики конкурентов, партнёров и поставщиков в программе 1С:Предприятие.

10 стартмани

16.07.2015    31311    3    Destroy    2    

И снова "Как сжать картинки для экспорта в EXCEL?" или Умная картинка 8.2

Практика программирования Загрузка и выгрузка в Excel v8 1cv8.cf Абонемент ($m)

Прошла уже эпоха , когда экономили на трафике интернета. Но все же...повторюсь. Я предлагаю совершенно новый способ сжатия картинки - эффект в 20 раз !!!

1 стартмани

17.06.2015    28553    43    Tatitutu    10    

Перенос справочников и документов из 1С 7.7 "Торговля и склад 9.2" в 1С 8.2 "Бухгалтерия предприятия 2.0".

Перенос данных из 1С7.7 в 1C8.X Обмен через XML v8 БП2.0 1С7:ТиС Россия Абонемент ($m)

Немного доработанные типовые правила обмена для конфигураций из ТиС 9.2. в БП 2.0 - «ПОД_Перенос_Справочников_ТиС_БП20.xml» и «ОбработкаВыгрузкиСправочников.ert». Добавлены правила выгрузки справочников: Организации, контрагенты и номенклатура. Доработал типовые ПОД для переноса только контрагентов и номенклатуры без документов в новую базу бухгалтерии 2.0, протестировал на типовых конфигурациях ТиС 9.2 рел.984 и БП 2.0.64.23.

1 стартмани

05.06.2015    48173    91    Kuzya_brаtsk    3    

Создание и сброс главного узла, Признак РИБ. 8.2 - 8.3

Распределенная БД (УРИБ, УРБД) v8 1cv8.cf Абонемент ($m)

Обработка предназначена для сброса и создания главного узла РИБ 8.2 - 8.3

1 стартмани

04.04.2015    38649    277    programmistSVS    7    

Загрузка товаров из таблицы в реализацию и поступление УТ 10.3 по артикулу и производителю + создание товаров и ГТД

Обработка документов Загрузка и выгрузка в Excel Оптовая торговля Учет ТМЦ Оптовая торговля Учет ТМЦ v8 УТ10 Россия УУ Абонемент ($m)

Обработка встраивается в конфигурацию (только кнопка для вызова обработки) и позволяет быстро и просто загрузить список товаров в реализацию или поступление. В процессе загрузки создаются отсутствующие товары и ГТД.

2 стартмани

03.03.2015    13807    2    taurus__    0    

Работа с Excel. Объединение, Стыковка, Свертка

Универсальные обработки Загрузка и выгрузка в Excel v8 1cv8.cf Абонемент ($m)

Обработка позволяет работать как с одним, так и с несколькими файлами Excel: Объединять файлы со сходной структурой в одну таблицу, Стыковать файлы с разной структурой по ключевому полю, Группировать результат по выбранным полям и суммировать числовые поля.

1 стартмани

19.02.2015    24577    23    Ekovichev    7    

Перенос данных из Бухгалтерии 2.0 в Бухгалтерию 3.0

Перенос данных из 1C8 в 1C8 Обмен через XML v8 БП2.0 БП3.0 Россия БУ Абонемент ($m)

Перенос данных и остатков с Бухгалтерии 2.0 в Бухгалтерию 3.0 с помощью универсального обмена данными XML.

1 стартмани

30.12.2014    43368    301    sergeyzhuravlev    10    

Нестандартная загрузка из Excel

Загрузка и выгрузка в Excel v8 1cv8.cf Абонемент ($m)

Взгляд на привычную задачу под неожиданным углом - пусть пользователь прямо в Excel решает, что ему надо, и грузит в 1С только нужное. Установите любой отбор, выделите фрагмент, и вот он уже в 1С. Для обычных и УФ 8.3

1 стартмани

12.11.2014    28890    51    Yashazz    45